| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| type(KORC_PARAMS), | intent(inout) | :: | params | Core KORC simulation parameters. |
||
| type(FIELDS), | intent(in) | :: | F | An instance of the KORC derived type FIELDS. |
||
| type(PROFILES), | intent(in) | :: | P | An instance of the KORC derived type PROFILES. |
||
| type(SPECIES), | intent(inout), | DIMENSION(:), ALLOCATABLE | :: | spp | An instance of the derived type SPECIES containing all the parameters and simulation variables of the different species in the simulation. |
subroutine adv_FOeqn_top(params,F,P,spp)
TYPE(KORC_PARAMS), INTENT(INOUT) :: params
!! Core KORC simulation parameters.
TYPE(FIELDS), INTENT(IN) :: F
!! An instance of the KORC derived type FIELDS.
TYPE(PROFILES), INTENT(IN) :: P
!! An instance of the KORC derived type PROFILES.
TYPE(SPECIES), DIMENSION(:), ALLOCATABLE, INTENT(INOUT) :: spp
!! An instance of the derived type SPECIES containing all the parameters
!! and simulation variables of the different species in the simulation.
REAL(rp), DIMENSION(8) :: Bmag
REAL(rp), DIMENSION(8) :: b_unit_X,b_unit_Y,b_unit_Z
REAL(rp), DIMENSION(8) :: v,vpar,vperp
REAL(rp), DIMENSION(8) :: tmp
REAL(rp), DIMENSION(8) :: g
REAL(rp), DIMENSION(8) :: cross_X,cross_Y,cross_Z
REAL(rp), DIMENSION(8) :: vec_X,vec_Y,vec_Z
REAL(rp),DIMENSION(8) :: X_X,X_Y,X_Z
REAL(rp),DIMENSION(8) :: V_X,V_Y,V_Z
REAL(rp),DIMENSION(8) :: B_X,B_Y,B_Z
REAL(rp),DIMENSION(8) :: E_X,E_Y,E_Z,PSIp
INTEGER(is),DIMENSION(8) :: flag_cache
REAL(rp) :: B0,EF0,R0,q0,lam,ar
REAL(rp) :: a,m_cache,q_cache
REAL(rp) :: ne0,Te0,Zeff0
INTEGER :: ii
!! Species iterator.
INTEGER :: pp
!! Particles iterator.
INTEGER :: cc
!! Chunk iterator.
INTEGER(ip) :: tt
!! time iterator.
do ii = 1_idef,params%num_species
m_cache=spp(ii)%m
q_cache=spp(ii)%q
a = q_cache*params%dt/m_cache
B0=F%Bo
EF0=F%Eo
lam=F%AB%lambda
R0=F%AB%Ro
q0=F%AB%qo
ar=F%AB%a
!$OMP PARALLEL DO default(none) &
!$OMP& FIRSTPRIVATE(E0,a,m_cache,q_cache,B0,EF0,lam,R0,q0,ar)&
!$OMP& shared(params,ii,spp,P,F) &
!$OMP& PRIVATE(pp,tt,Bmag,cc,X_X,X_Y,X_Z,V_X,V_Y,V_Z,B_X,B_Y,B_Z, &
!$OMP& E_X,E_Y,E_Z,b_unit_X,b_unit_Y,b_unit_Z,v,vpar,vperp,tmp, &
!$OMP& cross_X,cross_Y,cross_Z,vec_X,vec_Y,vec_Z,g,flag_cache,PSIp)
do pp=1_idef,spp(ii)%ppp,8
!$OMP SIMD
do cc=1_idef,8_idef
X_X(cc)=spp(ii)%vars%X(pp-1+cc,1)
X_Y(cc)=spp(ii)%vars%X(pp-1+cc,2)
X_Z(cc)=spp(ii)%vars%X(pp-1+cc,3)
V_X(cc)=spp(ii)%vars%V(pp-1+cc,1)
V_Y(cc)=spp(ii)%vars%V(pp-1+cc,2)
V_Z(cc)=spp(ii)%vars%V(pp-1+cc,3)
PSIp(cc)=spp(ii)%vars%PSI_P(pp-1+cc)
g(cc)=spp(ii)%vars%g(pp-1+cc)
flag_cache(cc)=spp(ii)%vars%flag(pp-1+cc)
end do
!$OMP END SIMD
if (.not.params%FokPlan) then
do tt=1_ip,params%t_skip
call analytical_fields_p(B0,EF0,R0,q0,lam,ar,X_X,X_Y,X_Z, &
B_X,B_Y,B_Z,E_X,E_Y,E_Z,flag_cache)
call advance_FOeqn_vars(tt,a,q_cache,m_cache,params, &
X_X,X_Y,X_Z,V_X,V_Y,V_Z,B_X,B_Y,B_Z,E_X,E_Y,E_Z, &
P,F,g,flag_cache,PSIp)
end do !timestep iterator
!$OMP SIMD
do cc=1_idef,8_idef
spp(ii)%vars%X(pp-1+cc,1)=X_X(cc)
spp(ii)%vars%X(pp-1+cc,2)=X_Y(cc)
spp(ii)%vars%X(pp-1+cc,3)=X_Z(cc)
spp(ii)%vars%V(pp-1+cc,1)=V_X(cc)
spp(ii)%vars%V(pp-1+cc,2)=V_Y(cc)
spp(ii)%vars%V(pp-1+cc,3)=V_Z(cc)
spp(ii)%vars%g(pp-1+cc) = g(cc)
spp(ii)%vars%flag(pp-1+cc) = flag_cache(cc)
spp(ii)%vars%B(pp-1+cc,1) = B_X(cc)
spp(ii)%vars%B(pp-1+cc,2) = B_Y(cc)
spp(ii)%vars%B(pp-1+cc,3) = B_Z(cc)
spp(ii)%vars%E(pp-1+cc,1) = E_X(cc)
spp(ii)%vars%E(pp-1+cc,2) = E_Y(cc)
spp(ii)%vars%E(pp-1+cc,3) = E_Z(cc)
end do
!$OMP END SIMD
else
!$OMP SIMD
do cc=1_idef,8_idef
B_X(cc)=spp(ii)%vars%B(pp-1+cc,1)
B_Y(cc)=spp(ii)%vars%B(pp-1+cc,2)
B_Z(cc)=spp(ii)%vars%B(pp-1+cc,3)
E_X(cc)=spp(ii)%vars%E(pp-1+cc,1)
E_Y(cc)=spp(ii)%vars%E(pp-1+cc,2)
E_Z(cc)=spp(ii)%vars%E(pp-1+cc,3)
end do
!$OMP END SIMD
call advance_FP3Deqn_vars(params,X_X,X_Y,X_Z,V_X,V_Y,V_Z, &
g,m_cache,B0,lam,R0,q0,EF0,B_X,B_Y,B_Z,E_X,E_Y,E_Z, &
P,F,flag_cache,PSIp)
!$OMP SIMD
do cc=1_idef,8_idef
spp(ii)%vars%V(pp-1+cc,1)=V_X(cc)
spp(ii)%vars%V(pp-1+cc,2)=V_Y(cc)
spp(ii)%vars%V(pp-1+cc,3)=V_Z(cc)
spp(ii)%vars%g(pp-1+cc) = g(cc)
end do
!$OMP END SIMD
end if
!$OMP SIMD
! !$OMP& aligned(Bmag,B_X,B_Y,B_Z, &
! !$OMP& b_unit_X,b_unit_Y,b_unit_Z,v,V_X,V_Y,V_Z,vpar, &
! !$OMP& vperp,tmp,cross_X,cross_Y,cross_Z, &
! !$OMP& vec_X,vec_Y,vec_Z,E_X,E_Y,E_Z)
do cc=1_idef,8_idef
!Derived output data
Bmag(cc) = SQRT(B_X(cc)*B_X(cc)+B_Y(cc)*B_Y(cc)+B_Z(cc)*B_Z(cc))
! Parallel unit vector
b_unit_X(cc) = B_X(cc)/Bmag(cc)
b_unit_Y(cc) = B_Y(cc)/Bmag(cc)
b_unit_Z(cc) = B_Z(cc)/Bmag(cc)
v(cc) = SQRT(V_X(cc)*V_X(cc)+V_Y(cc)*V_Y(cc)+V_Z(cc)*V_Z(cc))
if (v(cc).GT.korc_zero) then
! Parallel and perpendicular components of velocity
vpar(cc) = (V_X(cc)*b_unit_X(cc)+V_Y(cc)*b_unit_Y(cc)+ &
V_Z(cc)*b_unit_Z(cc))
vperp(cc) = v(cc)**2 - vpar(cc)**2
if ( vperp(cc) .GE. korc_zero ) then
vperp(cc) = SQRT( vperp(cc) )
else
vperp(cc) = 0.0_rp
end if
! Pitch angle
spp(ii)%vars%eta(pp-1+cc) = 180.0_rp* &
MODULO(ATAN2(vperp(cc),vpar(cc)),2.0_rp*C_PI)/C_PI
! Magnetic moment
spp(ii)%vars%mu(pp-1+cc) = 0.5_rp*m_cache* &
g(cc)**2*vperp(cc)**2/Bmag(cc)
! See Northrop's book (The adiabatic motion of charged
! particles)
! Radiated power
tmp(cc) = q_cache**4/(6.0_rp*C_PI*E0*m_cache**2)
cross_X(cc) = V_Y(cc)*B_Z(cc)-V_Z(cc)*B_Y(cc)
cross_Y(cc) = V_Z(cc)*B_X(cc)-V_X(cc)*B_Z(cc)
cross_Z(cc) = V_X(cc)*B_Y(cc)-V_Y(cc)*B_X(cc)
vec_X(cc) = E_X(cc) + cross_X(cc)
vec_Y(cc) = E_Y(cc) + cross_Y(cc)
vec_Z(cc) = E_Z(cc) + cross_Z(cc)
spp(ii)%vars%Prad(pp-1+cc) = tmp(cc)* &
( E_X(cc)*E_X(cc)+E_Y(cc)*E_Y(cc)+E_Z(cc)*E_Z(cc) + &
cross_X(cc)*E_X(cc)+cross_Y(cc)*E_Y(cc)+ &
cross_Z(cc)*E_Z(cc) + g(cc)**2* &
((E_X(cc)*V_X(cc)+E_Y(cc)*V_Y(cc)+E_Z(cc)*V_Z(cc))**2 &
- vec_X(cc)*vec_X(cc)-vec_Y(cc)*vec_Y(cc)- &
vec_Z(cc)*vec_Z(cc)) )
! Input power due to electric field
spp(ii)%vars%Pin(pp-1+cc) = q_cache*(E_X(cc)*V_X(cc)+ &
E_Y(cc)*V_Y(cc)+E_Z(cc)*V_Z(cc))
else
spp(ii)%vars%eta(pp-1+cc) = 0.0_rp
spp(ii)%vars%mu(pp-1+cc) = 0.0_rp
spp(ii)%vars%Prad(pp-1+cc) = 0.0_rp
spp(ii)%vars%Pin(pp-1+cc) = 0.0_rp
end if
end do
!$OMP END SIMD
end do !particle chunk iterator
!$OMP END PARALLEL DO
end do !species iterator
end subroutine adv_FOeqn_top